# LDperf.ctl: Collects Database Performance Reports
# $Id: LDperf.ctl,v 1.2 2015/11/16 16:04:04 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/DB/LDperf.ctl,v 1.2 2015/11/16 16:04:04 RDA Exp $
#
# Change History
# 20151113  JJU  Add OSWatcher reports

=head1 NAME

DB:LDperf - Collects Database Performance Reports

=head1 DESCRIPTION

=head2 results - Database Performance Tools

This module gets reports generated by database performance tools during the
last 15 days.

=cut

var %dsc = (\
  addm => {ttl => '---+ ADDM Results'},\
  ash  => {ttl => '---+ ASH Results',\
           zip => 'HTML Result'},\
  awr  => {ttl => '---+ AWR Results',\
           zip => 'HTML Result'},\
  awrd => {ttl => '---+ AWR Diff Results',\
           zip => 'HTML Result'},\
  osw  => {ttl => '---+ OSWatcher Results',\
           zip => 'Packaged Files'})

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

# Collect recent files
debug ' Inside LOAD module, gathering database performance reports'
call setAbbr('DB_PER_')
report results
title '---+!! Database Performance Tools Results'
title $TOC

loop $typ ('addm','ash','awr','awrd','osw')
{var $dsc = $dsc{$typ,'zip'}
 prefix
 {write $dsc{$typ,'ttl'}
  write '   * Limited to executions done in last 15 days%BR% '
  if ?$dsc
   write '|*Result*|*',$dsc,'*|'
  else
   write '|*Result*|'
 }
 loop $fil (grepDir(${OUT.E},concat('^',${CUR.W_PREFIX},'.*_',$typ,'\.htm$'),\
                    'itm15'))
 {var $bas = substr($fil,0,-4)
  if !?$dsc
   write '|[[../extern/',$bas,'.htm][_blank][',substr($bas,7),']]|'
  elsif testFile('fr',catFile(${OUT.E},concat($bas,'.zip')))
   write '|[[../extern/',$bas,'.htm][_blank][',substr($bas,7),\
       ']]|[[../extern/',$bas,'.zip][_blank][zip]]|'
  else
   write '|[[../extern/',$bas,'.htm][_blank][',substr($bas,7),']]| |'
 }
 if hasOutput(true)
  write $TOP
}
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Database Performance Tools]]'

=head1 SEE ALSO

L<DB:TLperf|collect::DB:TLperf>

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut