# DCes.ctl:344:Collects Oracle Entitlements Server Information
# $Id: DCes.ctl,v 1.6 2015/07/03 12:04:44 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCes.ctl,v 1.6 2015/07/03 12:04:44 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

OFM:DCes - Collects Oracle Entitlements Server Information

=head1 DESCRIPTION

This module collects information related to Oracle Entitlements Server,
formerly known as AquaLogic Enterprise Security.

The following reports can be generated and are regrouped under C<Entitlements
Server>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.ES module ...',tput('off')

# Initialization
var $ADMIN_HOME = ${D_ADMIN_HOME:''}
var $MW_HOME    = ${D_MW_HOME:''}
var $SSM_HOME   = ${D_SSM_HOME:''}
var $TAIL       = ${DFT.N_TAIL:1000}
var $VERSION    = ${T_ES_VERSION}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Entitlements Server'

# Load the common macros
run RDA:library()

=head1 ADMINISTRATION SERVER INFORMATION

=head2 Configuration Files

Gathers Administration Server-related configuration files (for versions
earlier than 11g).

=cut

if ?testDir('d',$MW_HOME)
{if compare('OLDER',$VERSION,'11')
 {debug ' Inside ES module, collecting the administration server config files'
  pretoc '2:Administration Server'
  pretoc '3:Configuration Files'
  call sort_files(4,0,grepDir(catDir($ADMIN_HOME,'config'),'^\.+$','pv'))
  unpretoc 2
 }

=head1 SECURITY SERVICE MODULE INFORMATION

=head2 Configuration Files

Gathers Security Service Module-related configuration files.

=cut

 pretoc '2:Security Service Module'
 var %ins = ()
 if compare('VALID',$VERSION,'11')
 {loop $ins (findDir($dir = catDir($SSM_HOME,'oes_sm_instances'),'^\.+$','nv'))
   var $ins{catDir($dir,$ins)} = $ins
 }
 else
 {loop $dir (catDir($SSM_HOME,'java-ssm','instance'),\
             catDir($SSM_HOME,'oracle-ssm','instance'),\
             catDir($SSM_HOME,'rmi-ssm','instance'),\
             catDir($SSM_HOME,'webservice-ssm','instance'),\
             catDir($SSM_HOME,'websphere-ssm','instance'),\
             catDir($SSM_HOME,'wls8-ssm','instance'),\
             catDir($SSM_HOME,'wls-ssm','instance'))
  {loop $ins (findDir($dir,'^\.+$','nv'))
    var $ins{catDir($dir,$ins)} = $ins
  }
 }
 debug ' Inside ES module, collecting the SSM configuration and log files'
 loop $dir (keys(%ins))
 {pretoc "3:'",$ins{$dir},"' Instance"
  pretoc '4:Configuration Files'
  call sort_files(5,0,grepDir(catDir($dir,'config'),'^\.+$','pv'))
  unpretoc

=head2 Log Files

Gathers Security Service Module-related log files.

=cut

  pretoc '4:Log Files'
  call sort_files(5,$TAIL,grepDir(catDir($dir,'log'),'\.log$','ip'))
  unpretoc 2
 }
 unpretoc
}

=head1 ORACLE WEBLOGIC SERVER DOMAIN INFORMATION

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domain.

=cut

toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
toc '%INCLUDE("OFM_WREQ_OFM_ES_WH_TF.toc")%'
toc '%POP2%'
toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Domain")%'
toc '%INCLUDE("OFM_WREQ_OFM_ES_DOM_TF.toc")%'
toc '%POP2%'

unpretoc

=head1 SEE ALSO

L<OFM:DCwreq|collect::OFM:DCwreq>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.26:  Srikanth Manduva.

=item RDA 8.07:  Srikanth Manduva.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut