# DCocs.ctl:240:Controls Oracle Collaboration Suite Data Collection
# $Id: DCocs.ctl,v 1.5 2013/10/30 07:18:33 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCocs.ctl,v 1.5 2013/10/30 07:18:33 RDA Exp $
#
# Change History
# 20130610  MSC  Improve validation.

=head1 NAME

OFM:DCocs - Controls Oracle Collaboration Suite Data Collection

=head1 DESCRIPTION

This module defines common settings for all Oracle Collaboration Suite modules
and gathers information that is common for Oracle Collaboration Suite
components.

The following reports can be generated and are regrouped under C<Oracle
Collaboration Suite>:

=cut

echo tput('bold'),'Processing OFM.OCS module ...',tput('off')

# Initialization
var $ORACLE_HOME = ${D_ORACLE_HOME/P:''}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Oracle Collaboration Suite'

=head2 virtual - Virtual Service

Gathers Virtual Service (Service to Service) information from the Oracle
Collaboration Suite installation.

=cut

if grepCommand(concat(catCommand($ORACLE_HOME,'bin','ldapsearch'),' -H 2>&1'),\
               '\s-q\s','f')
 var ($flg,$pgm) = (true,lastCommand())
elsif ?findCommand('ldapsearch')
 var ($flg,$pgm) = (false,last)
else
 var $pgm = undef
if $pgm
{debug ' Inside OCS module, about to gather virtual service information'

 var $hst = isHost(${T_LDAP_HOST},true)
 var $prt = isPort(${N_LDAP_PORT},true)

 # Perform the LDAP query
 if and($hst,$prt)
 {if $flg
  {var $out = getTemp('ldapsearch','.txt')
   var $cmd = concat($pgm,' -h ',$hst,' -p ',$prt,' -D "cn=orcladmin" -q \
                     -L -s sub -b "cn=Services,cn=OracleContext" \
                     "labeleduri=*" labeleduri >',$out,' 2>&1')
   output | $cmd
   call derivePassword('pseudo','host','orcladmin','LDAP_ORCLADMIN')
   call writePassword("%s\012",\
     'pseudo','host','orcladmin',"Enter 'orcladmin' user password:",'')
   close
   report virtual
   prefix
    write '---+ Virtual Service (Service to Service) Information'
   call writeFile($out)
   call unlinkTemp('ldapsearch')
  }
  else
  {var $cmd = concat($pgm,' -h ',$hst,' -p ',$prt,' -D "cn=orcladmin" -w %s \
                     -L -s sub -b "cn=Services,cn=OracleContext" \
                     "labeleduri=*" labeleduri 2>&1')
   report virtual
   prefix
    write '---+ Virtual Service (Service to Service) Information'
   call writeCommand({\
     cmd => $cmd,\
     pwd => ['pseudo','host','LDAP_ORCLADMIN',\
             "Enter 'orcladmin' user password:",'']})
  }
  if isCreated(true)
  {write $TOP
   toc '2:[[',getFile(),'][rda_report][Virtual Service]]'
  }
 }
}

# Disable the group title in next index
if isTocCreated()
 toc '-:Oracle Collaboration Suite'

=head1 SEE ALSO

L<OFM:DCcont|collect::OFM:DCcont>,
L<OFM:DCdscs|collect::OFM:DCdscs>,
L<OFM:DCmail|collect::OFM:DCmail>,
L<OFM:DCocal|collect::OFM:DCocal>,
L<OFM:DCrtc|collect::OFM:DCrtc>,
L<OFM:DCwac|collect::OFM:DCwac>,
L<OFM:DCwksp|collect::OFM:DCwksp>,
L<OFM:DCwmc|collect::OFM:DCwmc>,
L<OFM:DCwrls|collect::OFM:DCwrls>

=begin credits

=over 10

=item RDA 4.6:  Frederic Daurelle, Takayuki Hamaguchi.

=item RDA 4.7:  Frederic Daurelle.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut