# DCodc.ctl:357:Collects Oracle WebCenter Enterprise Capture Information
# $Id: DCodc.ctl,v 1.7 2015/07/03 12:04:44 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCodc.ctl,v 1.7 2015/07/03 12:04:44 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

OFM:DCodc - Collects Oracle WebCenter Enterprise Capture Information

=head1 DESCRIPTION

This module collects Oracle WebCenter Enterprise Capture-related information.

The following reports can be generated and are regrouped under C<WebCenter
Enterprise Capture>:

=head1 REPORTS

=cut

# Validate the platform
if !or(${RDA.B_WINDOWS},${RDA.B_CYGWIN})
 return

echo tput('bold'),'Processing OFM.ODC module ...',tput('off')

# Initialization
var $MNU = 'WebCenter Content'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

pretoc '^1:',$MNU

=head1 ORACLE WEBLOGIC SERVER DOMAIN COLLECTIONS

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domain.

=cut

if ?testFile('f',cleanPath([${GRP.INIT.D_ORACLE_HOME/P},upDir(),\
                            'registry.xml'],true))
{toc '%PUSH("%SPLIT%")%'
 toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
 toc '%INCLUDE("OFM_WREQ_OFM_ODC_WH_TF.toc")%'
 toc '%POP2%'
 toc '%PUSH("%SPLIT%")%'
 toc '%PUSH("1+:Oracle WebLogic Server Domain")%'
 toc '%INCLUDE("OFM_WREQ_OFM_ODC_DOM_TF.toc")%'
 toc '%POP2%'
}
else
{# Initialization
 var $AGE      = ${R_LOG_AGE/T:5}
 var $CS_LOG   = ${D_CS_LOG:''}
 var $IS_LOG   = ${D_IS_LOG:''}
 var $ODC_HOME = ${D_HOME:''}
 var $PPS_LOG  = ${D_PPS_LOG:''}
 var $RS_LOG   = ${D_RS_LOG:''}
 var $TAIL     = ${DFT.N_TAIL:1000}

 # Load the common macros
 run RDA:library()
 pretoc '1+:WebCenter Enterprise Capture'

=head1 ORACLE WEBCENTER ENTERPRISE CAPTURE COLLECTIONS

=head2 Commit Server

Collects Commit Server log files.

=cut

 debug ' Inside ODC module, collecting commit server log files'
 pretoc '2:Commit Server'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,\
   grepDir($CS_LOG,'^CS\d{2}-\d{2}-\d{4}\.LOG$',concat('ipm',$AGE)))
 unpretoc 2

=head2 Import Server

Collects Import Server log files.

=cut

 debug ' Inside ODC module, collecting import server log files'
 pretoc '2:Import Server'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,\
   grepDir($IS_LOG,'^IS\d{2}-\d{2}-\d{4}\.LOG$',concat('ipm',$AGE)))
 unpretoc 2

=head2 Recognition Server

Collects Recognition Server log files.

=cut

 debug ' Inside ODC module, collecting recognition server log files'
 pretoc '2:Recognition Server'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,\
   grepDir($RS_LOG,'^RS\d{2}-\d{2}-\d{4}\.LOG$',concat('ipm',$AGE)))
 unpretoc 2

=head1 ORACLE WEBCENTER DISTRIBUTED CAPTURE COLLECTIONS

Collects Oracle WebCenter Distributed Capture log files.

=cut

 debug ' Inside ODC module, collecting ODDC log files'
 pretoc '2:WebCenter Distributed Capture'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,\
   grepDir($PPS_LOG,'^PPS\d{2}\d{2}\d{4}\.LOG$',concat('ipm',$AGE)))
 unpretoc 3

=head2 not_found - Not found

Used as a warning when none of the Oracle WebCenter Enterprise Capture files
are found.

=cut

 if !isTocCreated()
 {debug ' Inside ODC module, no file found'
  report not_found
  write 'No Oracle WebCenter Enterprise Capture configuration files were found \
         and all files were optional. This does not mean there was necessarily \
         a problem with RDA, but it should be investigated.'
  toc '2:[[',getFile(),'][rda_report][Not found]]'
 }
}

# Disable the group title in next index
toc '-:',$MNU

=head1 SEE ALSO

L<OFM:DCecm|collect::OFM:DCecm>,
L<OFM:DCwreq|collect::OFM:DCwreq>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.21: Vince Cook.

=item RDA 8.03: Cindi Canfield.

=item RDA 8.05: Cindi Canfield.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut