# DCohs.ctl:307:Collects Oracle HTTP Server 12c Information
# $Id: DCohs.ctl,v 1.5 2015/07/03 12:04:44 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCohs.ctl,v 1.5 2015/07/03 12:04:44 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

OFM:DCohs - Collects Oracle HTTP Server 12c Information

=head1 DESCRIPTION

This module collects Oracle HTTP Server-related information. The module
covers Oracle HTTP Server 12c and later.

The following reports can be generated and are regrouped under C<Oracle HTTP
Server>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.OHS module ...',tput('off')

# Initialization
var $INSTALL     = ${W_INSTALL:'STANDALONE'}
var $ORACLE_HOME = ${D_ORACLE_HOME/P:''}
var $TAIL        = ${DFT.N_TAIL:1000}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Oracle HTTP Server'

# Load the common macros
run RDA:INVinfo()
run RDA:library()

=head1 ORACLE HOME COLLECTIONS

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Oracle HTTP Server home
collection.

=cut

debug ' Inside OHS module, collecting defined abbreviations'
report abbr
prefix
{write '---+ Oracle HTTP Server Home Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 product_info - Product Information

Gathers the product information.

=cut

if ?testDir('d',catDir($ORACLE_HOME,'inventory'))
{debug ' Inside OHS module, getting product information (can take time)'
 report product_info
 title '---+!! Product Information'
 title '---## From ',encode($ORACLE_HOME),' '
 title $TOC

 prefix
  write '---+ Files in OHS Oracle Home'
 call statDir('an',$ORACLE_HOME)
 if hasOutput(true)
  write $TOP

 call inventory_details(lastDir(),true)
 if isCreated()
  toc '2:[[',getFile(),'][rda_report][Product Information]]'
}

=head2 Installation and Configuration Files

Gathers the Oracle Fusion Middleware configuration and installation files.

=cut

debug ' Inside OHS module, gathering install and configuration information'
pretoc '2:Installation and Configuration Files'
call sort_files(3,$TAIL,\
  grepDir(catDir($ORACLE_HOME,'cfgtoollogs','oui'),'\.(err|log|out)$','np'),\
  grepDir(catDir($ORACLE_HOME,'cfgtoollogs','opatch'),'\.(log|txt)$','np'),\
  grepDir(catDir($ORACLE_HOME,'install'),'\.(ini|log)','dir'),\
  grepDir(catDir($ORACLE_HOME,'logs'),'\.log','np'),\
  grepDir(catDir($ORACLE_HOME,'network','log'),'\.log','np'))
unpretoc

=head2 ohs_bin - Executable List

Gathers the Oracle HTTP server executable list.

=cut

debug ' Inside OHS module, listing Oracle HTTP Server executables'
report ohs_bin
prefix
 write '---+ List of Files in ',encode($ORACLE_HOME)
loop $dir ($ORACLE_HOME,catDir($ORACLE_HOME,'ohs','bin'))
 call statDir('an',$dir)
if isCreated(true)
{write $TOP
 toc '2:[[',getFile(),'][rda_report][Executable List]]'
}

=head1 ORACLE WEBLOGIC SERVER DOMAIN COLLECTIONS

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domains.

=cut

# Analyze the domain requests
var %tbl = ()
loop $req (${CUR.O_SETUP}->search('^WREQ_OFM_OHS_DOM'))
{var $dom = $req->get_first('I_DOMAIN')
 if ?$dom->get_first('I_WL_HOME')
  var $tbl{last->get_oid,$req->get_oid} = $dom->get_first('T_DOMAIN_NAME')
 else
  var $tbl{'WH',$req->get_oid} = $dom->get_first('T_DOMAIN_NAME')
}

# Include the table of content files produced by WREQ
loop $oid (keys(%tbl))
{if $orp = compare('eq',$oid,'WH')
  toc '%PUSH("0:   * Orphan Domains")%'
 toc '%PUSH("%SPLIT%")%'
 if compare('eq',$INSTALL,'WLS')
  toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
 else
  toc '%PUSH("1+:Oracle HTTP Server Overview")%'
 toc '%INCLUDE("OFM_WREQ_OFM_OHS_',$oid,'_TF.toc")%'
 toc '%POP2%'
 loop $tid (keys($tbl = $tbl{$oid}))
 {toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1+:',"'",$tbl->{$tid},"'",' Domain")%'
  toc '%INCLUDE("OFM_',$tid,'_TF.toc")%'
  toc '%POP2%'
 }
 if $orp
  toc '%POP%'
}

unpretoc

=head1 SEE ALSO

L<OFM:DCwreq|collect::OFM:DCwreq>,
L<RDA:INVinfo|collect::RDA:INVinfo>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 8.04: Daniel Mortimer.

=item RDA 8.08: Daniel Mortimer.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut