# DCend.ctl:E999:Finalizes the Data Collection
# $Id: DCend.ctl,v 1.5 2015/04/21 11:49:25 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/RDA/DCend.ctl,v 1.5 2015/04/21 11:49:25 RDA Exp $
#
# Change History
# 20150421  MSC  Add a credential transfer mechanism.

=head1 NAME

RDA:DCend - RDA Module Finalizing the Data Collection

=head1 DESCRIPTION

This module finalizes the data collection.

=cut

use Mrc

echo tput('bold'),'Processing RDA.END module ...',tput('off')

# Initialization
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

# Identify the login name
var ${MOD.T_LOGNAME} = user()

# Identify the operating system module
var $run = check(getOsName(),'aix',           'OS:OSaix',\
                             'darwin',        'OS:OSdarwin',\
                             'dec_osf',       'OS:OSosf',\
                             'dynixptx',      'OS:OSptx',\
                             'hpux',          'OS:OShpux',\
                             'linux',         'OS:OSlinux',\
                             'solaris',       'OS:OSsunos',\
                             cond(isCygwin(), 'OS:OSwin32',\
                                  isUnix(),   'OS:OSunix',\
                                  isWindows(),'OS:OSwin32',\
                                  isVms(),    'OS:OSvms'))

=head2 system - System Information

Collects key system configuration for the CFG module.

=cut

debug ' Inside END module, gathering system information'
report system
write '---+ System Information'
run &{$run}('END_system')

=head2 files - Collected Files

Collects key system configuration for the CFG module.

=head2 report - Report Settings

Produces an overview report of the main current settings and the data
collection, as well as some statistics about the SQL statement and operating
system command execution for the CFG module.

=head2 target - Target Information

Produces an overview report of the defined targets for the CFG module.

=cut

collect MCend|END()

=pod

Defines post treatment when requested.

=cut

if ${MOD.ROOT.B_RUN}
{if ${DFT.B_FORCE_ROOT}
  var ($flg,@edt) = (true,\
                     'DFT/B_FORCE_ROOT=1',\
                     grep(@{MOD.ROOT.T_EDIT},'^DFT/B_FORCE_ROOT=','v'))
 else
  var ($flg,@edt) = (and(isUnix(),not(match(id(),'^uid=0\050'))),\
                     @{MOD.ROOT.T_EDIT})
 if $flg
 {var ${MOD.ROOT.T_POST_RENDER} = 'TOOL:RUNroot-remote'
  var ${MOD.ROOT.R_FACTOR:'Timeout incremental factor'} = \
    ${MOD.ROOT.R_FACTOR}
  var @{MOD.ROOT.T_EDIT:'TLroot edit specifications'} = @edt
  var ${MOD.ROOT.T_HOST:'Host for the TLroot session'} = \
    ${MOD.ROOT.T_HOST}
  var @{MOD.ROOT.T_PREFIX:'TLroot command prefix'} = \
    @{MOD.ROOT.T_PREFIX}
  var @{MOD.ROOT.T_TRANSFER:'TLroot credentials transfer'} = \
    @{MOD.ROOT.T_TRANSFER}
  var ${MOD.ROOT.T_USER:'User for the TLroot session'} = \
    ${MOD.ROOT.T_USER}
 }
}

=pod

Stores the time of the last RDA Data Collection execution and indicates the end
of the script.

=cut

var ${T_RPT_LAST} = ${RDA.T_TIMESTAMP}

echo ${RDA.T_LINE}
echo 'RDA Data Collection Ended ',${RDA.T_LOCALTIME}
echo ${RDA.T_LINE}

=head1 SEE ALSO

L<OS:OSaix|collect::OS:OSaix>,
L<OS:OSdarwin|collect::OS:OSdarwin>,
L<OS:OShpux|collect::OS:OShpux>,
L<OS:OSlinux|collect::OS:OSlinux>,
L<OS:OSosf|collect::OS:OSosf>,
L<OS:OSptx|collect::OS:OSptx>,
L<OS:OSsunos|collect::OS:OSsunos>,
L<OS:OSunix|collect::OS:OSunix>,
L<OS:OSvms|collect::OS:OSvms>,
L<OS:OSwin32|collect::OS:OSwin32>,
L<RDA:MCend|collect::RDA:MCend>

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut