# DChss.ctl:571:Collects Oracle Hyperion Shared Services Information
# $Id: DChss.ctl,v 1.12 2015/08/21 16:04:40 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/BI/DChss.ctl,v 1.12 2015/08/21 16:04:40 RDA Exp $
#
# Change History
# 20150821  MSC  Improve time consistency.

=head1 NAME

BI:DChss - Collects Oracle Hyperion Shared Services Information

=head1 DESCRIPTION

This module collects information for Oracle Hyperion Shared Services (HSS).

The following reports can be generated and is regrouped under C<Hyperion
Shared Services>:

=cut

echo tput('bold'),'Processing BI.HSS module ...',tput('off')

# Initialization
var $EPM_HOME = ${GRP.EPM.D_HOME:${ENV.EPM_ORACLE_HOME:${ENV.HYPERION_HOME:''}}}
var $TAIL     = ${N_TAIL:1000}

var $PRE = setPrefix()
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Hyperion Shared Services'

# Load the common macros
run BI:EPMlib()
run RDA:library()

# Limit password file request
var $EPM_VERSION = get_epm_version($EPM_HOME)
if and(compare('SAME',$EPM_VERSION,'11.1.2.2'),\
       compare('OLDER',$EPM_VERSION,'11.1.2.2.300'))
{var $epm = createTemp('EPMPWD','.tmp',false)
 call derivePassword('host','BI:EPM','epmsys_registry','EPM_REGISTRY')
 call writeTempPassword('EPMPWD',"%s\012",'host','BI:EPM','epmsys_registry',\
   'Enter Shared Services database password:','')
 call closeTemp('EPMPWD')
}

=head1 ORACLE HOME INFORMATION

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Hyperion Shared Services home
collection.

=cut

debug ' Inside HSS module, collecting defined home abbreviations'
report abbr
prefix
{write '---+ Hyperion Shared Services Home Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 Configuration Files

Gets configuration files.

=cut

debug ' Inside HSS module, gathering configuration files'
pretoc '2:Configuration Files'
call sort_files(3,0,\
  catFile($EPM_HOME,'common','config','11.1.2.0','reg.properties'),\
  catFile($EPM_HOME,'common','config','11.1.2.0','resources','logging',\
          'logging.xml'),\
  catFile($EPM_HOME,'common','config','11.1.2.0','resources','registry',\
          'logging.xml'),\
  catFile($EPM_HOME,'common','utilities','LCM','11.1.2.0','conf',\
          'logging.xml'),\
  catFile($EPM_HOME,'common','utilities','UpdateNativeDir',\
          'CSSClientLogging.xml'),\
  catFile($EPM_HOME,'products','FinancialManagement','logging',\
          'InteropLogging.xml'),\
  catFile($EPM_HOME,'upgrades','foundation','conf','logging.xml'))
unpretoc

=head2 Log Files

Gets log files.

=cut

debug ' Inside HSS module, gathering log files'
pretoc '2:Log Files'
call sort_files(3,$TAIL,\
  grepDir(catDir($EPM_HOME,'logs','hsf','debug'),'^SharedServices','inp'))
unpretoc

=head1 PRODUCT REPORTS

=head2 cssconfig - CSS Configuration

Exports the CSS Configuration using
F<$HYPERION_HOME/common/config/9.5.0.0/epmsys_registry.sh> or
F<$HYPERION_HOME/common/config/9.5.0.0/epmsys_registry.bat> (on versions
earlier than 11.1.2).

=cut

if !@ins = ${CUR.O_MODULE}->search('^OI')
{debug ' Inside HSS module, getting the CSS Configuration'
 call collect_cssconfig(2,catDir($EPM_HOME,'common','config','9.5.0.0'),$epm)

=head2 Oracle WebLogic Server Information

Includes the Oracle WebLogic reports generated by the
L<abr:WREQ|collect::OFM:DCwreq> module for the associated Oracle WebLogic
Server domain (on versions earlier than 11.1.2 having a product registry).

=cut

 if ?${GRP.EPM.D_DOMAIN}
 {var $dom = basename(last)
  toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
  toc '%INCLUDE("OFM_WREQ_BI_HSS_WH_TF.toc")%'
  toc '%POP2%'
  toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1+:',"'",$dom,"'",' Domain")%'
  toc '%INCLUDE("OFM_WREQ_BI_HSS_DOM_TF.toc")%'
  toc '%POP2%'
 }
}

=head1 DEPLOYMENT REPORTS

Available on version 11.1.2 and later.

=cut

else
{var $CNT = 0
 loop $itm (@ins)
 {var ($ins,$uid) = ($itm->get_first('D_HOME'),$itm->get_oid)
  call setSymbol('$EPM_INSTANCE',$ins)
  call setPrefix(concat($PRE,'i',incr($CNT)))
  pretoc '%SPLIT%'
  pretoc "1+:'",basename($ins),"' Deployment"

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Hyperion Shared Services
instance collection.

=cut

  debug ' Inside HSS module, collecting defined instance abbreviations'
  report abbr
  prefix
  {write '---+ Hyperion Shared Services Instance Abbreviations'
   write '|*Abbreviation*|*Location*|'
  }
  var %hsh = getSymbols()
  loop $key (keys(%hsh))
   write '|',$key,' |',$hsh{$key},' |'
  if isCreated(true)
   toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 CSS Configuration

Exports the CSS Configuration using
F<$INSTANCE_HOME/bin/epmsys_registry.sh> or
F<$INSTANCE_HOME/bin/epmsys_registry.bat>.

=cut

  debug ' Inside HSS module, getting the CSS Configuration'
  call collect_cssconfig(2,catDir($ins,'bin'),$epm)

=head2 Logging Configuration

Collects the logging configuration files from the F<$INSTANCE_HOME/config>, and
F<$INSTANCE_HOME/diagnostics/logs> directory.

=cut

  debug ' Inside HSS module, getting the logging configuration files'
  pretoc '2:Configuration Files'
  call sort_files(3,0,\
    catFile($ins,'config','foundation','11.1.2.0','reg.properties'),\
    catFile($ins,'config','foundation','11.1.2.0','.oracle.instance.products'),\
    catFile($ins,'config','FoundationServices','logging.xml'),\
    catFile($ins,'config','FoundationServices','migration.properties'),\
    catFile($ins,'config','FoundationServices','CCS.xml'),\
    catFile($ins,'config','FoundationServices','CMS.properties'),\
    catFile($ins,'config','FoundationServices','DBPool.properties'),\
    catFile($ins,'config','FoundationServices',\
            'LCMRegistryDisplay.properties'),\
    catFile($ins,'config','ReportingAnalysis','syncCSSId','logging.xml'),\
    catFile($ins,'diagnostics','logs','foundation','conf',\
            'hssupgrade.properties'))
  unpretoc

=head2 diaglogs - Diagnostic Log Files

Collects the diagnostic log files from the F<$INSTANCE_HOME/diagnostics/logs>
directory.

=cut

  report diaglogs
  var $log = catDir($ins,'diagnostics','logs')
  var %pat = (\
    config             => '^(SharedServices.*\.log|registry\.log)$',\
    epma               => '^SharedServices',\
    essbase            => '^SharedServices',\
    FoundationServices => '^SharedServices',\
    hfm                => '^InteropJava\.log$',\
    install            => '^(hfm-cacls-lcmservice|hss-install\.log$)',\
    migration          => '^LCM',\
    registry           => '^registry\.log$',\
    catDir('registry','velocity') => '^velocity\.log$',\
    ReportingAnalysis  => '^eiengine\.log$',\
    services           => '^HyS9FoundationServices.*\.log$')
  prefix
  {write '---+!! Diagnostic Log Files'
   write '---## From: ',$log
   if $TAIL
    write '   * Last ',$TAIL,' lines from the log files captured'
   write '   * Links point to files that have been collected in their original \
               format. Opening them directly in your browser can present \
               risks. To prevent them, access the file outside the browser or \
               use the link to save them and use an adequate viewer.'
   write '|*File Name*| *Size*|*Last Modified Date*|'
  }
  loop $sub ('config','epma','essbase',catDir('essbase','lcm'),\
             'FoundationServices','hfm','install','migration','registry',\
             catDir('registry','velocity'),'ReportingAnalysis','services',\
             catDir('upgrades','foundation'))
  {loop $fil (grepDir(catDir($log,$sub),nvl($pat{$sub},'\.(log|csv)$'),'ipt'))
   {var $lnk = encode($fil)
    var $siz = getSize($fil)
    if $siz
    {output => d,concat('L_',basename($fil))
     if cond($TAIL,${CUR.O_LAST}->write_tail($fil,$TAIL),\
                   ${CUR.O_LAST}->write_data($fil))
      var $lnk = concat('[[',${CUR.O_LAST}->get_raw(true),\
                        '][_blank][',$lnk,']]')
     end ${CUR.O_LAST}
    }
    write '|',$lnk,' | ',$siz,'|',getLastModify($fil,'<UTC>'),' |'
   }
  }
  if isCreated(true)
   toc '2:[[',getFile(),'][rda_report][Diagnostic Log Files]]'

=head2 diagreport - Diagnostic Report Files

Collects the diagnostic report files from the
F<$INSTANCE_HOME/diagnostics/reports> directory.

=cut

  report diagreport
  var $log = catDir($ins,'diagnostics','reports')
  var %pat = (services => 'Foundation')
  prefix
  {write '---+!! Diagnostic Report Files'
   write '---## From: ',$log
   write '   * Links point to files that have been collected in their original \
               format. Opening them directly in your browser can present \
               risks. To prevent them, access the file outside the browser or \
               use the link to save them and use an adequate viewer.'
   write '|*File Name*| *Size*|*Last Modified Date*|'
  }
  loop $sub ('FoundationServices','registry','migration','services',\
            catDir('upgrades','foundation'))
  {loop $fil (grepDir(catDir($log,$sub),nvl($pat{$sub},'^[^\.]+'),'ipt'))
   {var $lnk = encode($fil)
    var $siz = getSize($fil)
    if $siz
    {output d,concat('L_',basename($fil))
     if ${CUR.O_LAST}->write_data($fil)
      var $lnk = concat('[[',${CUR.O_LAST}->get_raw(true),\
                        '][_blank][',$lnk,']]')
     end ${CUR.O_LAST}
    }
    write '|',$lnk,' | ',$siz,'|',getLastModify($fil,'<UTC>'),' |'
   }
  }
  if isCreated(true)
   toc '2:[[',getFile(),'][rda_report][Diagnostic Report Files]]'

=head2 Oracle WebLogic Server Information

Includes the Oracle WebLogic Server reports generated by the
L<abr:WREQ|collect::OFM:DCwreq> module for the associated Oracle WebLogic
Server domain.

=cut

  if ${CUR.O_SETUP}->search(concat('^WREQ_BI_HSS_',replace($uid,'^OI','DOM')))
  {var ($req) = last
   var $dom = $req->get_first('I_DOMAIN')
   var $oid = $dom->get_first('I_WL_HOME')->get_oid
   var $nam = $dom->get_first('T_DOMAIN_NAME')
   toc '%PUSH("%SPLIT%")%'
   toc '%PUSH("1++:Oracle WebLogic Server Overview")%'
   toc '%INCLUDE("OFM_WREQ_BI_HSS_',$oid,'_TF.toc",1)%'
   toc '%POP2%'
   toc '%PUSH("%SPLIT%")%'
   toc '%PUSH("1++:',"'",$nam,"'",' Domain")%'
   toc '%INCLUDE("OFM_',$req->get_oid,'_TF.toc",1)%'
   toc '%POP2%'
  }
  unpretoc 2

  # Restore module prefix
  call setPrefix($PRE)
 }
}

# Unlink the temporary password file when existing
if ?$epm
 call unlinkTemp('EPMPWD')

unpretoc

=head1 SEE ALSO

L<BI:EPMlib|collect::BI:EPMlib>,
L<OFM:DCwreq|collect::OFM:DCwreq>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.21: Venkat Maddipati.

=item RDA 4.23: Venkat Maddipati.

=item RDA 4.24: Maurice Bauhahn, Venkat Maddipati.

=item RDA 4.28: Maurice Bauhahn.

=item RDA 4.29: Maurice Bauhahn.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut