# MCdt.ctl:258: Collects StorEdge T3 Information
# $Id: MCdt.ctl,v 1.5 2013/10/30 07:18:25 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/EXPLORER/MCdt.ctl,v 1.5 2013/10/30 07:18:25 RDA Exp $
#
# Change History
# 20130829  JGS  Improve SENA commands.

=head1 NAME

EXPLORER:MCdt - Collects StorEdge T3 Information

=head1 DESCRIPTION

Collects StorEdge T3 information.

The following reports can be generated and are regrouped under C<StorEdge T3>:

=cut

use Buffer
use Mrc

# Initialization
var $VALIDATE = true
keep $VALIDATE

section begin

var $ERR = '---## Associated Errors'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

run EXPLORER:XPLRlib('t3')

# -----------------------------------------------------------------------------
# XPLR_t3 section
# -----------------------------------------------------------------------------

section XPLR_t3

# Validate the execution context
if !${B_GLOBAL:true}
 return
call log_run('Processing T3 sections...')

pretoc '2: StorEdge T3'

=head2 t3_cmd_scsi_${DEV} - SCSI Drives

For each drive (DEV) returned by the F</usr/sbin/format> command, collects the
command C</usr/sbin/format -e -f ${FIL} -d ${DEV}>. ${FIL} holds the format
command file, which is created as part of this collection.

=cut

if ?testFile('f','/usr/sbin/format')
{# Adjust environment to avoid format to trigger luflist commands
 var $env = setEnv('NOINUSE_CHECK',1)

 # Validate the context
 if !grepCommand('/usr/sbin/format </dev/null','(SUN-T300)|(SUN-T4)','f')
 {call setEnv('NOINUSE_CHECK',$env)
  return log_info('T3 and T4 not installed')
 }

 # Create the format command file
 var $fil = createTemp('FCF')
 call writeTemp('FCF','scsi')
 call writeTemp('FCF','inquiry')
 call writeTemp('FCF','quit')
 call writeTemp('FCF','quit')
 call closeTemp('FCF')

 # Get the SUN-T3 drives from the disk list
 debug '  Inside T3 collection, gathering SCSI commands'
 pretoc '3: SCSI Drives'

 loop $lin (command('/usr/sbin/format </dev/null 2>&1'))
 {next !match($lin,'(\w+)\s*.SUN-T3')
  var ($dev) = last

  # Collect SCSI drive information for each drive found
  report concat('t3_cmd_scsi_',$dev)
  title '---+!! SCSI Drive ',$dev,' Information'
  prefix
  {write '---## Using: /usr/sbin/format -e -f <script> -d ',$dev
   call beginBlock(true)
   call addBlock('E','D',concat('disks/t3/',$dev,'.scsiinfo'))
  }

  if loadCommand(concat('/usr/sbin/format -e -f ',$fil,' -d ',$dev,' 2>&1'))
  {var $buf = getLastBuffer()
   while $buf->grep('Inquiry:','fr')
   {while ?$buf->get_line()
    {var $lin = last
     break match($lin,'scsi>')
     write $lin
    }
   }
   if hasOutput(true)
   {call endBlock()
    write $TOP
   }
  }

  if isCreated(true)
   toc '4:[[',getFile(),'][rda_report][',$dev,']]'
 }

 # Remove the format command file and restore the environment
 call unlinkTemp('FCF')
 call setEnv('NOINUSE_CHECK',$env)

 # Adjust the table of contents
 unpretoc
}

=head2 SENA Drives

For each Sun Enterprise Network Array (SENA) returned by the
C</usr/sbin/luxadm probe> command, collects the following commands:

=over 2

=item o C</usr/sbin/luxadm display ${SENA}>

=item o C</usr/sbin/luxadm -e dump_map ${SENA}>

=back

=cut

if ?testFile('f','/usr/sbin/luxadm')
{debug '  Inside T3 collection, gathering SENA commands'
 pretoc '3: SENA Drives'

 # Determine the SENAs
 var %dev = ()
 loop $dev (grepCommand('/usr/sbin/luxadm probe 2>/dev/null',\
                        '^\s+Node.*WWN:(\w+)','1'))
  var $dev{$dev} = 1

 # Collect commands for each SENA
 loop $dev (keys(%dev))
 {# Determine the commands to collect
  var @cmd = (\
    [concat('disks/t3/luxadm_display_',$dev),\
     '/usr/sbin/luxadm',concat('display ',$dev),\
     '---+ Device Data'],\
    [concat('disks/t3/luxadm_-e_dump_map_',$dev),\
     '/usr/sbin/luxadm',concat('-e dump_map ',$dev),\
     '---+ World Wide Name Data'])

  # Generate the report
  report concat('t3_cmd_sena_',$dev)
  title '---+!! Sun Enterprise Network Array ',$dev,' Information'
  title $TOC
  loop $rec (@cmd)
  {sleep
   call do_exec($rec)
  }
  if isCreated(true)
   toc '4:[[',getFile(),'][rda_report][',$dev,']]'
 }

 # Adjust the table of contents
 unpretoc
}

# Adjust the table of contents
unpretoc

=head1 SEE ALSO

L<EXPLORER:DCxplr|collect::EXPLORER:DCxplr>,
L<EXPLORER:XPLRlib|collect::EXPLORER:XPLRlib>

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut