# MCfacc.ctl:250: Collects Flash Accelerator Cards Information
# $Id: MCfacc.ctl,v 1.5 2015/01/07 18:50:29 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/EXPLORER/MCfacc.ctl,v 1.5 2015/01/07 18:50:29 RDA Exp $
#
# Change History
# 20150107  PRA  Add F20 flash accelerator cards information collection.

=head1 NAME

EXPLORER:MCfacc - Collects Flash Accelerator Cards Information

=head1 DESCRIPTION

This module collects information about installed F20 and F40 flash accelerator
cards.

=cut

use Mrc

# Initialization
var $VALIDATE = true
keep $VALIDATE

section begin

var $ERR = '---## Associated Errors'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

run EXPLORER:XPLRlib('facc')

# -----------------------------------------------------------------------------
# XPLR_facc section
# -----------------------------------------------------------------------------

section XPLR_facc

# Validate the execution context
if !${B_GLOBAL:true}
 return
call log_run('Processing FACC sections...')

=head2 facc - Flash Accelerator Cards

Collects F20 Flash Accelerator Cards information using
F</opt/sun-ssm/sbin/fwupdate> or F</usr/sbin/fwupdate> with the following
arguments:

=over 2

=item o C<list controller>

=item o C<list disk>

=back

Also collects F40 Flash Accelerator Cards information using F</usr/bin/ddcli>
or F</usr/sbin/ddcli> with the following arguments:

=over 2

=item o C<-listall>

=item o C<-c ${DEVICE ID} -health>

=item o C<-c ${DEVICE ID} -list>

=item o C<-c ${DEVICE ID} -showvpd>

=back

=cut

# Generate the report
debug ' Inside FACC collection, gathering information for installed flash cards'
report facc
title '---+!! Flash Accelerator Cards Information'
title $TOC

# Collect F20 flash accelerator cards information
if ?$pgm = nvl(testFile('x','/opt/sun-ssm/sbin/fwupdate'),\
               testFile('x','/usr/sbin/fwupdate'))
 call do_exec(\
   [concat('flash/fwupdate_list_controller'),\
    $pgm,'list controller',\
    '---+ Controller Information'],\
   [concat('flash/fwupdate_list_disk'),\
    $pgm,'list disk',\
    '---+ Disk Information'])

# Collect F40 flash accelerator cards information
if ?$pgm = nvl(testFile('x','/usr/bin/ddcli'),\
               testFile('x','/usr/sbin/ddcli'))
{var @tbl = command(concat($pgm,' -listall'))
 call do_exec(\
   {cmd => 'ARRAY',\
    det => concat($pgm,' -listall'),\
    nam => 'flash/F40/ddcli_listall.out',\
    tbl => \@tbl,\
    ttl => '---+ Installed Flash Accelerator Cards'})
 loop $rec (@tbl)
 {next not(($id) = match($rec,'^(\S+)\s*ELP-4x100-4d-n'))
  call do_exec(\
    {cmd => 'TITLE', txt => concat('---+ F40 Card Id: ',$id)},\
    [concat('flash/F40/ddcli_c_',$id,'_list'),\
     $pgm,concat('-c ',$id,' -list'),\
     '---++ Physical Device Information'],\
    [concat('flash/F40/ddcli_c_',$id,'_health'),\
     $pgm,concat('-c ',$id,' -health'),\
     '---++ Health Status Information'],\
    [concat('flash/F40/ddcli_c_',$id,'_showvpd'),\
     $pgm,concat('-c ',$id,' -showvpd'),\
     '---++ Vital Product Data Information'])
 }
}

if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Flash Accelerator Cards]]'

=head1 SEE ALSO

L<EXPLORER:DCxplr|collect::EXPLORER:DCxplr>,
L<EXPLORER:XPLRlib|collect::EXPLORER:XPLRlib>

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut