# MCfru.ctl:248: Collects Field Replaceable Units (FRU) Information
# $Id: MCfru.ctl,v 1.5 2016/02/17 22:03:44 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/EXPLORER/MCfru.ctl,v 1.5 2016/02/17 22:03:44 RDA Exp $
#
# Change History
# 20160217 MM initialize $osv

=head1 NAME

EXPLORER:MCfru - Collects Field Replaceable Units (FRU) Information

=head1 DESCRIPTION

This module collects Field Replaceable Units (FRU) information.

=cut

use Mrc

# Initialization
var $VALIDATE = true
keep $VALIDATE

section begin

var $ERR = '---## Associated Errors'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

run EXPLORER:XPLRlib('fru')

#------------------------------------------------------------------------------
# XPLR_fru section
#------------------------------------------------------------------------------

section XPLR_fru

# Validate the execution context
if !${OS.solaris}
 return
if !${B_GLOBAL:true}
 return
call log_run('Processing FRU sections ...')
if !is_pkg_installed('SUNWfruid')
 return log_info('FRUid not installed')

=head2 fru - Field Replaceable Units (FRU)

Gathers Field Replaceable Units (FRU) information using the
C</usr/sbin/prtfru -x> command on:

=over 2

=item o

Non Sun Fire 15K servers regardless of the operating system release level.

=item o

Sun Fire 15K servers running Oracle Solaris 8 with patch 110460-23 or 108528-28
(or a later revision) applied.

=item o

Sun Fire 15K servers running Oracle Solaris 9 with patch 112959-01 (or a later
revision) applied.

=item o

Sun Fire 15K servers running Oracle Solaris 10 or later.

=back

=cut

debug ' Inside FRU collection, gathering FRU information'
report fru

var $osv = get_osv()

if or(is_explicit(),\
      not(or(is_pkg_installed('SUNWSMSr'),\
             grepCommand('/usr/bin/uname -i',\
                         'SUNW,Sun-Fire-15000|SUNW,Netra-T12'))),\
      check(get_osv(),'^8$',check_patch('108528','29','SUNWfruid'),\
                      '^9$',check_patch('112959','01','SUNWfruid'),\
                      true))
 call do_exec(\
   ['fru/prtfru_-x',\
    '/usr/sbin/prtfru','-x',\
    '---+ Field Replaceable Unit Information (in XML Format)'])
else
{var @txt = (concat('SunOS release level is ',$osv),\
             'FRU data not collected on SF15Ks and Sun Fire V1280 running \
              SunOS 5.8 or 5.9 unless patches 110460-23 or later, 108528-29 or \
              later for SunOS 5.8 and 112959-01 or later for SunOS 5.9 are \
              installed.')
 call do_exec(\
   {cmd => 'ARRAY',\
    nam => 'fru.error',\
    tbl => \@txt,\
    ttl => '---+ Field Replaceable Unit Information (in XML Format)'})
}

if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Field Replaceable Units (FRU)]]'

=head1 SEE ALSO

L<EXPLORER:DCxplr|collect::EXPLORER:DCxplr>,
L<EXPLORER:XPLRlib|collect::EXPLORER:XPLRlib>

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut